/*
 * Linker script for UNDI ELF32 files with seperate text and data
 * segments
 *
 * $Id: ldscript.undi,v 1.3 2005/03/17 22:18:44 gkminix Exp $
 */
OUTPUT_FORMAT("elf32-i386")
OUTPUT_ARCH(i386)
FORCE_COMMON_ALLOCATION
SECTIONS
{
  . = 0x0;
  .text 0 : AT(0)
  {
    *(.text)
    __text_end = .;
    *(.initext*)
    __initext_end = .;
  }
  .data 0 : AT(LOADADDR(.text) + ((SIZEOF(.text) + 0xF) & ~(0xF)))
  {
    __data_start = .;
    *(.rodata*)
    *(.data)
    CONSTRUCTORS
    __data_end  =  .;
  }
  .bss : AT(LOADADDR(.data) + SIZEOF(.data))
  {
    __bss_start = .;
   *(.bss)
   *(COMMON)
   __bss_end = ALIGN(4);
  }
  PROVIDE(__file_size = LOADADDR(.data) - LOADADDR(.text) + SIZEOF(.data));
  PROVIDE(__stack_size = 0);
  PROVIDE(__heap_size = 0);
}

